Altova RaptorXML Server 2025

Este ejemplo de código Visual Basic se divide en varias partes:

•Preparar e inicializar el objeto .NET de RaptorXML

•Validar un archivo XML

•Transformación XSLT y devolución del resultado en forma de cadena de texto

•Procesamiento de un documento XQuery y devolución del resultado en forma de archivo

•Preparación de la secuencia de ejecución del código y de su punto de entrada

Option Explicit On

Imports Altova.RaptorXMLServer

Module RaptorXMLRunner

  ' El objeto .NET de RaptorXML

    Dim objRaptor As Server

  ' Inicializar el objeto .NET de RaptorXML

    Sub Init()

     ' Asignar un objeto RaptorXML

       objRaptor = New Server()

     ' Configurar el servidor: notificación de errores, nombre y puerto del servidor HTTP (IPv6 localhost en este ejemplo)

       objRaptor.ErrorLimit = 1

       objRaptor.ReportOptionalWarnings = True

       objRaptor.ServerName = "::1"

       objRaptor.ServerPort = 8087                

    End Sub

  ' Validar un archivo

    Sub ValidateXML()

     ' Obtener una instancia del validador del objeto RaptorXML

       Dim objXMLValidator As XMLValidator

       objXMLValidator = objRaptor.GetXMLValidator()

     ' Configurar los datos de entrada

       objXMLValidator.InputFileName = "MiArchivoXML.xml"

     ' Validar; si el archivo no es válido, notificar el problema devuelto por RaptorXML

       If (objXMLValidator.IsValid()) Then

          Console.WriteLine("La cadena de entrada es válida")

       Else

          Console.WriteLine(objXMLValidator.LastErrorMessage)

       End If

    End Sub

  ' Realizar una transformación; devolver el resultado en forma de cadena de texto

    Sub RunXSLT()

     ' Obtener una instancia del motor XSLT del objeto servidor

       Dim objXSLT As XSLT

       objXSLT = objRaptor.GetXSLT()

     ' Configurar los datos de entrada

       objXSLT.InputXMLFileName = "MiArchivoXML.xml"

       objXSLT.XSLFileName = "MiTransformación.xsl"

     ' Ejecutar la transformación; si se ejecuta correctamente, se devuelve el resultado; si hay errores, devolver  una lista de errores

       Console.WriteLine(objXSLT.ExecuteAndGetResultAsString())

    End Sub

  ' Ejecutar un XQuery; guardar el resultado en un archivo

    Sub RunXQuery()

     ' Obtener una instancia del motor XQuery del objeto servidor

       Dim objXQ As XQuery

       objXQ = objRaptor.GetXQuery()

     ' Configurar los datos de entrada

       objXQ.InputXMLFileName = "MyXMLFile.xml"

       objXQ.XQueryFileName = "MyQuery.xq"

     ' Configurar la serialización (opcional para mejorar el formato del archivo de salida)

       objXQ.OutputEncoding = "UTF8"

       objXQ.OutputIndent = true

       objXQ.OutputMethod = "xml"

       objXQ.OutputOmitXMLDeclaration = false

     ' Ejecutar la consulta; el resultado se serializa en la ruta de acceso indicada

       objXQ.Execute( "MyQueryResult.xml" )

    End Sub

    Sub Main()

     ' Punto de entrada; realizar todas las funciones de muestra

       Init()

       ValidateXML()

       RunXSLT()

       RunXQuery()

    End Sub

End Module